Gecko [ dataharbor.africa ]

Name	Size	Permission
apache_accesses	4.32 KB	-rwxr-xr-x
apache_processes	5.67 KB	-rwxr-xr-x
apache_volume	4.27 KB	-rwxr-xr-x
cpu	6.59 KB	-rwxr-xr-x
df	4.27 KB	-rwxr-xr-x
df_inode	4.34 KB	-rwxr-xr-x
diskstats	34.19 KB	-rwxr-xr-x
entropy	983 B	-rwxr-xr-x
exim_mailqueue	3.19 KB	-rwxr-xr-x
exim_mailstats	5.51 KB	-rwxr-xr-x
forks	1000 B	-rwxr-xr-x
fw_packets	1.68 KB	-rwxr-xr-x
http_loadtime	2.52 KB	-rwxr-xr-x
if_err_eth0	3.03 KB	-rwxr-xr-x
if_eth0	5.71 KB	-rwxr-xr-x
interrupts	2.08 KB	-rwxr-xr-x
irqstats	4.17 KB	-rwxr-xr-x
load	2.68 KB	-rwxr-xr-x
memory	8.85 KB	-rwxr-xr-x
munin_stats	3.42 KB	-rwxr-xr-x
mysql_bytes	1.71 KB	-rwxr-xr-x
mysql_innodb	5.35 KB	-rwxr-xr-x
mysql_queries	2.5 KB	-rwxr-xr-x
mysql_slowqueries	1.49 KB	-rwxr-xr-x
mysql_threads	1.6 KB	-rwxr-xr-x
netstat	2.83 KB	-rwxr-xr-x
open_files	1.38 KB	-rwxr-xr-x
open_inodes	1.05 KB	-rwxr-xr-x
proc_pri	1.44 KB	-rwxr-xr-x
processes	11.62 KB	-rwxr-xr-x
swap	1.21 KB	-rwxr-xr-x
threads	1.05 KB	-rwxr-xr-x
uptime	853 B	-rwxr-xr-x
users	2.44 KB	-rwxr-xr-x
vmstat	1.08 KB	-rwxr-xr-x

Code Editor : apache_processes

#!/usr/local/cpanel/3rdparty/perl/536/bin/perl
# -*- cperl -*-

=head1 NAME

apache_processes - Munin plugin to monitor the number of
apache-processes running on the machine.

=head1 APPLICABLE SYSTEMS

Apache HTTP servers with C</whm-server-status> enabled.

=head1 CONFIGURATION

The plugin needs access to http://localhost/whm-server-status?auto (or
modify the URL for another host). See your Apache documentation on
how to set up this URL in your httpd.conf. Apache needs ExtendedStatus
enabled for this plugin to work.

Tip: To see if it's already set up correctly, just run this plugin
with the parameter "autoconf". If you get a "yes", everything should
work like a charm already.

This configuration section shows the defaults of the plugin:

[apache_*]
     env.url   http://127.0.0.1:%d/whm-server-status?auto
     env.ports 80
     env.showfree 1

The %d in the url will be replaced with the port.  The default port is
80 as shown. 'showfree' enables the disaplay of the "free slots" graph.

The port list is a space separated list of ports.  NOTE that one
single Apache can have several open ports, and the plugin needs only
to contact one to get the servers global status.  The list of ports is
only needed if you have several B<different> Apaches configured on
your host.

If you need authenticated access to the URL you can specify the
username and password in the URL.  For example:

[apache_volume]
     env.url http://munin:spamalot@localhost/whm-server-status?auto

This will provide for HTTP basic authentication.

=head1 INTERPRETATION

The plugin shows the number of Apache processes running on the
machine, and in addition separate "busy" and "idle" servers count.

If there is a flat ceiling effect on the graph where the number of
servers does not increase any more, in spite of no idle servers, then
the server has probably reached its C<MaxClients> setting.  In this
case it's very likely that some clients are getting connection refused
or some other problem when connecting to your server.  In this case
increase the C<MaxClients> setting.  Unless there is also no more free
memory.

=head1 MAGIC MARKERS

#%# family=auto
  #%# capabilities=autoconf

=head1 BUGS

Does not support digest authentication.

=head1 VERSION

$Id$

=head1 AUTHOR

Unknown

=head1 LICENSE

GPLv2

=cut

use strict;
use warnings;
use Munin::Plugin;

my $ret = undef;
if (! eval "require LWP::UserAgent;")
{
	$ret = "LWP::UserAgent not found";
        if ( ! defined $ARGV[0] ) {
                die $ret;
        }
}

my $URL = exists $ENV{'url'} ? $ENV{'url'} : "http://127.0.0.1:%d/whm-server-status?auto";
my @PORTS = exists $ENV{'ports'} ? split(' ', $ENV{'ports'}) : (80);
my $SHOWFREE = !exists $ENV{'showfree'} || $ENV{'showfree'};

if ( defined $ARGV[0] and $ARGV[0] eq "autoconf" )
{
	if ($ret)
	{
		print "no ($ret)\n";
		exit 0;
	}
	my $ua = LWP::UserAgent->new(timeout => 30,
			agent => sprintf("munin/%s (libwww-perl/%s)", $Munin::Common::Defaults::MUNIN_VERSION, $LWP::VERSION));

foreach my $port (@PORTS) {
                my $url = sprintf $URL, $port;
                my $response = $ua->request(HTTP::Request->new('GET',$url));
                if ($response->is_success) {
                        if ($response->content =~ /^Total Accesses:/im ){
                                next;
                        }
                        else {
                                print "no (ExtendedStatus option for apache" 
				      . " mod_status is missing on port $port)\n";
                                exit 0;
                        }
                }
                elsif ($response->code == 404)  {
                        print "no (apache server-status not found. check if mod_status is enabled)\n";
                        exit 0;
                }
                else {
                        print "no (Port $port: ". $response->message .")\n";
                        exit 0;
                }
	}
	print "yes\n";
	exit 0;
}

if ( defined $ARGV[0] and $ARGV[0] eq "config" )
{
        print "graph_title Apache processes\n";
        print "graph_args --base 1000 -l 0\n";
		print "graph_category apache\n";
	print "graph_order ";
	foreach my $port (@PORTS) {
	    print "busy$port idle$port ";
	}
	print "\n";
        print "graph_vlabel processes\n";
        print "graph_total total\n";
	foreach my $port (@PORTS) {
	    print "busy$port.label busy servers $port\n";
	    if (@PORTS == 1) {
		print "busy$port.draw AREA\n";
		print "busy$port.colour 33cc00\n";
	    }
	    else
	    {
		print "busy$port.draw LINE2\n";
	    }
	    print "idle$port.label idle servers $port\n";
	    print "idle$port.draw STACK\n";
	    print "idle$port.colour 0033ff\n";
	    if ($SHOWFREE) {
		print "free$port.label free slots $port\n";
		print "free$port.draw STACK\n";
		print "free$port.colour ccff00\n";
	    }
	}
	foreach my $port (@PORTS) {
		foreach my $type (qw(busy idle)) {
			print_thresholds("$type$port");
		}
	}
	exit 0;
}

foreach my $port (@PORTS)
{
    my $ua = LWP::UserAgent->new(timeout => 30,
			agent => sprintf("munin/%s (libwww-perl/%s)", $Munin::Common::Defaults::MUNIN_VERSION, $LWP::VERSION));
    my $url = sprintf $URL, $port;
    my $response = $ua->request(HTTP::Request->new('GET',$url));
    if ($response->content =~ /^Busy(?:Servers|Workers):\s+(.+)$/im) {
	    print "busy$port.value $1\n";
    } else {
	    print "busy$port.value U\n";
    }
    if ($response->content =~ /^Idle(?:Servers|Workers):\s+(.+)$/im) {
	    print "idle$port.value $1\n";
    } else {
	    print "idle$port.value U\n";
    }
    if ($SHOWFREE) {
	    if ($response->content =~ /^(Scoreboard: .*)$/m) {
		my $count = () = $1 =~ /\./g;
		print "free$port.value $count\n";
	    } else {
		print "free$port.value U\n";
	    }
    }
}

# vim:syntax=perl

${this.title}

Code Editor : apache_processes