Gecko [ dataharbor.africa ]

Name	Size	Permission
autofs4.meta	397 B	-rw-r--r--
autofs4.stp	4.07 KB	-rwxr-xr-x
connect_stat.meta	404 B	-rw-r--r--
connect_stat.stp	1019 B	-rwxr-xr-x
dropwatch.meta	494 B	-rw-r--r--
dropwatch.stp	871 B	-rwxr-xr-x
net_xmit_json.meta	453 B	-rw-r--r--
net_xmit_json.stp	1.76 KB	-rw-r--r--
netdev.meta	389 B	-rw-r--r--
netdev.stp	1.42 KB	-rwxr-xr-x
netfilter_drop.meta	630 B	-rw-r--r--
netfilter_drop.stp	1.13 KB	-rwxr-xr-x
netfilter_summary.meta	587 B	-rw-r--r--
netfilter_summary.stp	591 B	-rwxr-xr-x
netfilter_summary.txt	2.81 KB	-rw-r--r--
netfilter_summary_json.meta	511 B	-rw-r--r--
netfilter_summary_json.stp	1.04 KB	-rw-r--r--
nettop.meta	519 B	-rw-r--r--
nettop.stp	1.12 KB	-rwxr-xr-x
nettop.txt	953 B	-rw-r--r--
nfsd-recent.meta	423 B	-rw-r--r--
nfsd-recent.stp	442 B	-rwxr-xr-x
nfsd-trace.meta	314 B	-rw-r--r--
nfsd-trace.stp	701 B	-rw-r--r--
nfsd-trace.txt	876 B	-rw-r--r--
nfsd_unlink.meta	479 B	-rw-r--r--
nfsd_unlink.stp	523 B	-rwxr-xr-x
nfsdtop.meta	405 B	-rw-r--r--
nfsdtop.stp	3.31 KB	-rwxr-xr-x
packet_contents.meta	550 B	-rw-r--r--
packet_contents.stp	216 B	-rwxr-xr-x
packet_contents.txt	2.02 KB	-rw-r--r--
sk_stream_wait_memory.meta	616 B	-rw-r--r--
sk_stream_wait_memory.stp	999 B	-rwxr-xr-x
socket-trace.meta	702 B	-rw-r--r--
socket-trace.stp	222 B	-rwxr-xr-x
socktop	8.93 KB	-rwxr-xr-x
socktop.meta	548 B	-rw-r--r--
socktop.txt	4.04 KB	-rw-r--r--
stp_dump.meta	339 B	-rw-r--r--
stp_dump.stp	568 B	-rw-r--r--
stp_dump.txt	1.59 KB	-rw-r--r--
tcp_connections.meta	625 B	-rw-r--r--
tcp_connections.stp	361 B	-rwxr-xr-x
tcp_init_cwnd.meta	589 B	-rw-r--r--
tcp_init_cwnd.stp	343 B	-rwxr-xr-x
tcp_retransmission.meta	286 B	-rw-r--r--
tcp_retransmission.stp	1.15 KB	-rw-r--r--
tcp_trace.meta	684 B	-rw-r--r--
tcp_trace.stp	18.36 KB	-rwxr-xr-x
tcp_trace.txt	3.38 KB	-rw-r--r--
tcpdumplike.meta	381 B	-rw-r--r--
tcpdumplike.stp	581 B	-rwxr-xr-x
tcpipstat.meta	725 B	-rw-r--r--
tcpipstat.stp	17.82 KB	-rwxr-xr-x
tcpipstat.txt	898 B	-rw-r--r--
who_sent_it.meta	583 B	-rw-r--r--
who_sent_it.stp	477 B	-rw-r--r--
who_sent_it.txt	803 B	-rw-r--r--

Code Editor : autofs4.stp

#!/usr/bin/stap

// Copyright (c) 2009, 2015 Red Hat Inc.
//
// This file is part of systemtap, and is free software.  You can
// redistribute it and/or modify it under the terms of the GNU General
// Public License (GPL); either version 2, or (at your option) any
// later version.

probe kernel.function("autofs4_lookup") !,
      module("autofs4").function("autofs4_lookup")
{
        /*
         * Don't log automounts travels in its own directory hierarchy, as
         * they are treated differently, and certainly not something that is
         * useful for admins to see.
         */
        if (!isinstr(execname(), "automount")) {
                printf("%s process %s[%d] looking up %s%s\n",
                       ctime(gettimeofday_s()), execname(), pid(),
		       (@defined($nd) ? fullpath_struct_nameidata($nd)
			: inode_name($dir)),
                       d_name($dentry));
        }
}

probe kernel.function("autofs4_follow_link") !,
      module("autofs4").function("autofs4_follow_link")
{
        if (!isinstr(execname(), "automount")) {
                /*
                 * dentry->d_name will be '/' for the mount trigger.  Thus,
                 * the path that the trigger lives on is one level up the
                 * directory stack, and the root of that is yet another level
                 * up.
                 */
                printf("%s process %s[%d] following mount trigger %s\n",
                       ctime(gettimeofday_s()), execname(), pid(),
                       (@defined($nd) ? d_path($nd)
			: reverse_path_walk($dentry)))
        }
}

probe kernel.function("autofs4_expire_direct").return !,
      module("autofs4").function("autofs4_expire_direct").return ?
{
        if ($return != 0) {
	    if (@defined($mnt->mnt_mountpoint)) {
                        relative_path = reverse_path_walk(@entry($mnt->mnt_mountpoint))
	                root_path = sprintf("/%s", reverse_path_walk(@entry($mnt->mnt_parent->mnt_mountpoint)))
		}
		else {
			relative_path = ""
			root_path = task_dentry_path(task_current(), @entry($mnt->mnt_root), @entry($mnt))
		}
                printf("%s process %s[%d] expiring direct mount %s/%s\n",
                       ctime(gettimeofday_s()), execname(), pid(),
                       root_path, relative_path)
        }
}

/*
probe
module("autofs4").statement("autofs4_expire_direct@fs/autofs4/expire.c+17").nearest ?
{
        relative_path = reverse_path_walk($mnt->mnt_mountpoint)
        root_path = reverse_path_walk($mnt->mnt_parent->mnt_mountpoint)
        printf("%s process %s[%d] expiring direct mount /%s/%s\n",
               ctime(gettimeofday_s()), execname(), pid(),
               root_path, relative_path)
}
*/

probe kernel.function("autofs4_expire_indirect").return !,
      module("autofs4").function("autofs4_expire_indirect").return
{
        if ($return != 0) {
                relative_path = reverse_path_walk($return)

root_path = (@defined($mnt->mnt_root)
			     ? task_dentry_path(task_current(),
						@entry($mnt->mnt_root), @entry($mnt))
			     : reverse_path_walk(@entry($mnt->mnt_mountpoint)))
                printf("%s process %s[%d] expiring indirect mount %s/%s\n",
                       ctime(gettimeofday_s()), execname(), pid(),
                       root_path, relative_path)
        }
}

/*
 * The struct dentry's name may be '/' if this is a mount trigger, which
 * is not really something that is useful to print out.  Instead, we just
 * indicate whether a mount or umount succeeded or failed.  Coupled with the
 * messages printed out when looking up a directory and traversing a symlink,
 * this should be relatively easy to correlate to the appropriate directory.
 */
probe kernel.function("autofs4_wait").return !,
      module("autofs4").function("autofs4_wait").return
{
        if (@entry($notify) > 0) {
                dname = d_name(@entry($dentry))
                printf("%s %s of %s %s\n",
                       ctime(gettimeofday_s()),
                       (@entry($notify)==1?"mount":"unmount"),
                       dname,
                       $return == 0?"succeeded":"failed")
        }
}

${this.title}

Code Editor : autofs4.stp