Gecko [ dataharbor.africa ]

Name	Size	Permission
aux_syscalls.stp	3.58 KB	-rw-r--r--
sysc_arch_prctl.stp	3.21 KB	-rw-r--r--
sysc_compat_execve.stp	1.59 KB	-rw-r--r--
sysc_compat_fadvise64.stp	6.92 KB	-rw-r--r--
sysc_compat_fallocate.stp	3.54 KB	-rw-r--r--
sysc_compat_ftruncate64.stp	3.34 KB	-rw-r--r--
sysc_compat_lookup_dcookie.stp	3.72 KB	-rw-r--r--
sysc_compat_readahead.stp	3.18 KB	-rw-r--r--
sysc_compat_truncate64.stp	3.45 KB	-rw-r--r--
sysc_execve.stp	1.62 KB	-rw-r--r--
sysc_get_thread_area.stp	3.18 KB	-rw-r--r--
sysc_iopl.stp	2.27 KB	-rw-r--r--
sysc_mmap.stp	4.04 KB	-rw-r--r--
sysc_mmap2.stp	2.62 KB	-rw-r--r--
sysc_pipe32.stp	1.54 KB	-rw-r--r--
sysc_set_thread_area.stp	3.13 KB	-rw-r--r--
sysc_sigaltstack.stp	2.24 KB	-rw-r--r--
sysc_sysctl32.stp	1.12 KB	-rw-r--r--
sysc_vm86_warning.stp	1.17 KB	-rw-r--r--
syscall_num.stp	53.77 KB	-rw-r--r--

Code Editor : sysc_arch_prctl.stp

# arch_prctl _________________________________________________
# long sys_arch_prctl(int code, unsigned long addr)
# SYSCALL_DEFINE2(arch_prctl, int, option, unsigned long, arg2)
# COMPAT_SYSCALL_DEFINE2(arch_prctl, int, option, unsigned long, arg2)
#
# NOTE: x86_64 only.
#

@define _SYSCALL_ARCH_PRCTL_NAME
%(
	name = "arch_prctl"
%)

@define _SYSCALL_ARCH_PRCTL_ARGSTR
%(
	argstr = sprintf("%s, %u", code_str, addr)
%)

@define _SYSCALL_ARCH_PRCTL_REGARGS
%(
	code = int_arg(1)
	code_str = _stp_arch_prctl_func_str(code)
	addr = ulong_arg(2)
%)

probe syscall.arch_prctl = dw_syscall.arch_prctl !,
                           nd_syscall.arch_prctl {}
probe syscall.arch_prctl.return = dw_syscall.arch_prctl.return !,
                                  nd_syscall.arch_prctl.return {}

# dw_arch_prctl _____________________________________________________

probe dw_syscall.arch_prctl = kernel.function("sys_arch_prctl").call,
	kernel.function("compat_sys_arch_prctl").call ?
{
	@_SYSCALL_ARCH_PRCTL_NAME
	code = __int32(@choose_defined($code, $option))
	code_str = _stp_arch_prctl_func_str(code)
	addr = __ulong(@choose_defined($addr, $arg2))
	@_SYSCALL_ARCH_PRCTL_ARGSTR
}
probe dw_syscall.arch_prctl.return = kernel.function("sys_arch_prctl").return,
	kernel.function("compat_sys_arch_prctl").return ?
{
	@_SYSCALL_ARCH_PRCTL_NAME
	@SYSC_RETVALSTR($return)
}

# nd_arch_prctl _____________________________________________________

probe nd_syscall.arch_prctl = nd1_syscall.arch_prctl!, nd2_syscall.arch_prctl!, tp_syscall.arch_prctl
  { }

probe nd1_syscall.arch_prctl = kprobe.function("sys_arch_prctl"),
	kprobe.function("compat_sys_arch_prctl") ?
{
	@_SYSCALL_ARCH_PRCTL_NAME
	// NB: no asmlinkage()
	@_SYSCALL_ARCH_PRCTL_REGARGS
	@_SYSCALL_ARCH_PRCTL_ARGSTR
}

/* kernel 4.17+ */
probe nd2_syscall.arch_prctl = kprobe.function(@arch_syscall_prefix "sys_arch_prctl"),
	kprobe.function(@arch_syscall_prefix "compat_sys_arch_prctl") ?
{
	__set_syscall_pt_regs(pointer_arg(1))
	@_SYSCALL_ARCH_PRCTL_NAME
	@_SYSCALL_ARCH_PRCTL_REGARGS
	@_SYSCALL_ARCH_PRCTL_ARGSTR
}

/* kernel 3.5+, but undesirable because it affects all syscalls */
probe tp_syscall.arch_prctl = kernel.trace("sys_enter")
{
	__set_syscall_pt_regs($regs)
	@__syscall_compat_gate(@const("__NR_arch_prctl"), @const("__NR_ia32_arch_prctl"))
	@_SYSCALL_ARCH_PRCTL_NAME
	@_SYSCALL_ARCH_PRCTL_REGARGS
	@_SYSCALL_ARCH_PRCTL_ARGSTR
}

probe nd_syscall.arch_prctl.return = nd1_syscall.arch_prctl.return!, nd2_syscall.arch_prctl.return!, tp_syscall.arch_prctl.return
  { }
  
probe nd1_syscall.arch_prctl.return = kprobe.function("sys_arch_prctl").return,
	kprobe.function("compat_sys_arch_prctl").return ?
{
	@_SYSCALL_ARCH_PRCTL_NAME
	@SYSC_RETVALSTR(returnval())
}

/* kernel 4.17+ */
probe nd2_syscall.arch_prctl.return = kprobe.function(@arch_syscall_prefix "sys_arch_prctl").return,
      kprobe.function(@arch_syscall_prefix "compat_sys_arch_prctl").return ?
{
	@_SYSCALL_ARCH_PRCTL_NAME
	@SYSC_RETVALSTR(returnval())
}
 
/* kernel 3.5+, but undesirable because it affects all syscalls */
probe tp_syscall.arch_prctl.return = kernel.trace("sys_exit")
{
	__set_syscall_pt_regs($regs)
	@__syscall_compat_gate(@const("__NR_arch_prctl"), @const("__NR_ia32_arch_prctl"))
	@_SYSCALL_ARCH_PRCTL_NAME
	@SYSC_RETVALSTR($ret)
}

${this.title}

Code Editor : sysc_arch_prctl.stp