Gecko [ dataharbor.africa ]

Name	Size	Permission
aux_syscalls.stp	3.58 KB	-rw-r--r--
sysc_arch_prctl.stp	3.21 KB	-rw-r--r--
sysc_compat_execve.stp	1.59 KB	-rw-r--r--
sysc_compat_fadvise64.stp	6.92 KB	-rw-r--r--
sysc_compat_fallocate.stp	3.54 KB	-rw-r--r--
sysc_compat_ftruncate64.stp	3.34 KB	-rw-r--r--
sysc_compat_lookup_dcookie.stp	3.72 KB	-rw-r--r--
sysc_compat_readahead.stp	3.18 KB	-rw-r--r--
sysc_compat_truncate64.stp	3.45 KB	-rw-r--r--
sysc_execve.stp	1.62 KB	-rw-r--r--
sysc_get_thread_area.stp	3.18 KB	-rw-r--r--
sysc_iopl.stp	2.27 KB	-rw-r--r--
sysc_mmap.stp	4.04 KB	-rw-r--r--
sysc_mmap2.stp	2.62 KB	-rw-r--r--
sysc_pipe32.stp	1.54 KB	-rw-r--r--
sysc_set_thread_area.stp	3.13 KB	-rw-r--r--
sysc_sigaltstack.stp	2.24 KB	-rw-r--r--
sysc_sysctl32.stp	1.12 KB	-rw-r--r--
sysc_vm86_warning.stp	1.17 KB	-rw-r--r--
syscall_num.stp	53.77 KB	-rw-r--r--

Code Editor : sysc_set_thread_area.stp

# set_thread_area ____________________________________________
/*
 * asmlinkage int
 * sys_set_thread_area(struct user_desc __user *u_info)
 * asmlinkage long sys32_set_thread_area(struct user_desc __user *u_info)
 */

@define _SYSCALL_SET_THREAD_AREA_NAME
%(
	name = "set_thread_area"
%)

@define _SYSCALL_SET_THREAD_AREA_ARGSTR
%(
	argstr = sprintf("%s", u_info_str)
%)

@define _SYSCALL_SET_THREAD_AREA_REGARGS
%(
	u_info_uaddr = pointer_arg(1)
	u_info_str = _struct_user_desc_u(u_info_uaddr)
%)

probe syscall.set_thread_area = dw_syscall.set_thread_area !, nd_syscall.set_thread_area ? {}
probe syscall.set_thread_area.return = dw_syscall.set_thread_area.return !, nd_syscall.set_thread_area.return ? {}

# dw_set_thread_area _____________________________________________________

probe dw_syscall.set_thread_area = kernel.function("sys_set_thread_area") ?,
	kernel.function("sys32_set_thread_area") ?
{
	@_SYSCALL_SET_THREAD_AREA_NAME
	u_info_uaddr = $u_info
	u_info_str = _struct_user_desc_u(u_info_uaddr)
	@_SYSCALL_SET_THREAD_AREA_ARGSTR
}
probe dw_syscall.set_thread_area.return =
	kernel.function("sys_set_thread_area").return ?,
	kernel.function("sys32_set_thread_area").return ?
{
	@_SYSCALL_SET_THREAD_AREA_NAME
	@SYSC_RETVALSTR($return)
}

# nd_set_thread_area _____________________________________________________

probe nd_syscall.set_thread_area = nd1_syscall.set_thread_area!, nd2_syscall.set_thread_area!, tp_syscall.set_thread_area
  { }

probe nd1_syscall.set_thread_area = kprobe.function("sys_set_thread_area") ?,
	kprobe.function("sys32_set_thread_area") ?
{
	@_SYSCALL_SET_THREAD_AREA_NAME
	asmlinkage()
	@_SYSCALL_SET_THREAD_AREA_REGARGS
	@_SYSCALL_SET_THREAD_AREA_ARGSTR
}

/* kernel 4.17+ */
probe nd2_syscall.set_thread_area =
	kprobe.function(@arch_syscall_prefix "sys_set_thread_area") ?
{
	__set_syscall_pt_regs(pointer_arg(1))
	@_SYSCALL_SET_THREAD_AREA_NAME
	@_SYSCALL_SET_THREAD_AREA_REGARGS
	@_SYSCALL_SET_THREAD_AREA_ARGSTR
}

/* kernel 3.5+, but undesirable because it affects all syscalls */
probe tp_syscall.set_thread_area = kernel.trace("sys_enter")
{
	__set_syscall_pt_regs($regs)
	@__syscall_compat_gate(@const("__NR_set_thread_area"), @const("__NR_ia32_set_thread_area"))
	@_SYSCALL_SET_THREAD_AREA_NAME
	@_SYSCALL_SET_THREAD_AREA_REGARGS
	@_SYSCALL_SET_THREAD_AREA_ARGSTR
}

probe nd_syscall.set_thread_area.return = nd1_syscall.set_thread_area.return!, nd2_syscall.set_thread_area.return!, tp_syscall.set_thread_area.return
  { }

probe nd1_syscall.set_thread_area.return =
	kprobe.function("sys_set_thread_area").return ?,
	kprobe.function("sys32_set_thread_area").return ?
{
	@_SYSCALL_SET_THREAD_AREA_NAME
	@SYSC_RETVALSTR(returnval())
}

/* kernel 4.17+ */
probe nd2_syscall.set_thread_area.return =
	kprobe.function(@arch_syscall_prefix "sys_set_thread_area").return ?
{
	@_SYSCALL_SET_THREAD_AREA_NAME
	@SYSC_RETVALSTR(returnval())
}

/* kernel 3.5+, but undesirable because it affects all syscalls */
probe tp_syscall.set_thread_area.return = kernel.trace("sys_exit")
{
	__set_syscall_pt_regs($regs)
	@__syscall_compat_gate(@const("__NR_set_thread_area"), @const("__NR_ia32_set_thread_area"))
	@_SYSCALL_SET_THREAD_AREA_NAME
	@SYSC_RETVALSTR($ret)
}

${this.title}

Code Editor : sysc_set_thread_area.stp